***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 17, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4FL14A  A K 
.param
+vc0 = 6.806e-11	   vc1 = 3.766e-11        vc2 = 1.000		vc3 = 1.205e-12		vc4 = 3.065e-1
+tc1 = 2.221e-2	   tc2 = 1.061e-2		  tc3 = 1.501e-2		tc4 = 3.871e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {2.105e-1*min(i,0)}
d1 A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 9.947e-15	       n = 1.002          rs = 1.360e-2
+ibv = 1.0e-3		 nbv = 0.5        bv = 16.40
+ikf = 2.387
***** capacitance parameter *****
+cjo = 9.123e-10	   m = 3.392e-1		  vj = 6.530e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		      eg = 1.100		      xti = 3
+tikf = 6.0e-3          
+tbv1 =7.487e-4	      tbv2 = -7.452e-8
.ends P4FL14A
*$
